Hi,

shouldn't be a problem. What overriding in vfp is, should become clear now:

local li
lo = CREATEOBJECT("overSuper")
lo = CREATEOBJECT("SubSub")
lo = CREATEOBJECT("SubDoDef")
lo = CREATEOBJECT("SubEmpty")
lo = CREATEOBJECT("SubComm")
lo = CREATEOBJECT("SubDef_in")
lo = CREATEOBJECT("SubDef_out")


DEFINE CLASS oversuper as Custom
	lFlag = .f.
	FUNCTION init
		this.lFlag = .t.
	ENDFUNC

	FUNCTION destroy
		? PADR(this.Class, 12) + ;
			IIF(this.lFlag, "All Ok", "has a problem")
	endfunc
ENDDEFINE

DEFINE CLASS subSub as oversuper
	FUNCTION init
		RETURN DODEFAULT()
	endfunc
ENDDEFINE

DEFINE CLASS subDoDef as oversuper
	FUNCTION init
		RETURN DODEFAULT()
	endfunc
ENDDEFINE

DEFINE CLASS subEmpty as oversuper
	FUNCTION init
	endfunc
ENDDEFINE

DEFINE CLASS subComm as oversuper
	FUNCTION init
		*
	endfunc
ENDDEFINE

DEFINE CLASS subdef_in as oversuper
	FUNCTION init
		#if .f.
		#endif
	endfunc
ENDDEFINE

DEFINE CLASS subdef_out as oversuper
	#if .f.
		FUNCTION init
		endfunc
	#endif
enddefine

HTH

thomas