>Does set deleted off work in creating recordset?

Sure it does. Check series of set commands support by VFPOLEDB driver. Below is a sample asp code :

<%
    cSQLSelect = "select cust_id,company,contact," & _
                 "iif(deleted(),'Deleted',space(len('Deleted'))) as DelStat from customer"

    dbpath = Server.MapPath("data")
    set oConnection = Server.CreateObject( "adodb.connection" ) 
    with oConnection
       .ConnectionString = "Provider=VFPOLEDB.1;data source=" & dbpath & "\testdata.dbc"
       .Open
       .Errors.Clear	
       .Execute( "set deleted off" )
       Set rs = .Execute( cSQLSelect )
    end with
    ' Check results
    Response.Write("<TABLE border='1'><TR><TD>Cust Id</TD><TD>Company</TD><TD>Contact</TD><TD>Status</TD></TR>" )
    while not rs.eof
            Response.Write("<TR>")
            Response.Write("<TD>" & rs.Fields("cust_id").value & "</TD>")
            Response.Write("<TD>" & rs.Fields("company").value & "</TD>")
            Response.Write("<TD>" & rs.Fields("contact").value & "</TD>")
            Response.Write("<TD>" & rs.Fields("DelStat").value & "</TD>")
            Response.Write("</TR>")
            rs.MoveNext
    wend
    Response.Write("</TABLE><BR/>")
	
    oConnection.Close
    set oConnection = nothing
%>

Cetin