Here is how I do it (just had to do this today as a matter of fact):

STORE ALIAS() TO scrollalias
PRIVATE osetcontrol
IF TYPE("_screen.activeform.activecontrol")="O" .and. !ISNULL(_screen.activeform.activecontrol)
	IF UPPER(_screen.activeform.name)="PROFILEFORM"
		osetcontrol = _screen.activeform.activecontrol
	ENDIF
ENDIF
oldscreen1 = ofrmProfile.lockscreen
ofrmProfile.lockscreen = .T.
*--1st grid on form ofrmprofile
IF TYPE('ofrmProfile.pgfProfile.pagPolicy.accountgrid')="O" .and. !ISNULL(ofrmProfile.pgfProfile.pagPolicy.accountgrid)
	WITH ofrmProfile.pgfProfile.pagPolicy.accountgrid
		SELECT TACCOUNT && recordsource of grid
		.SetFocus()
		FOR i= 1 TO .ActiveRow-1
	   	 .DoScroll(0)
		ENDFOR
	ENDWITH
ENDIF
*--2nd grid on form ofrmprofile
IF TYPE('ofrmProfile.pgfProfile.pagPolicy.policygrid')="O" .and. !ISNULL(ofrmProfile.pgfProfile.pagPolicy.policygrid)
	WITH ofrmProfile.pgfProfile.pagPolicy.policygrid
		SELECT TPOLICY  && recordsource of grid
		.SetFocus()
		FOR i= 1 TO .ActiveRow-1
	   	 .DoScroll(0)
		ENDFOR
	ENDWITH
ENDIF
IF !EMPTY(scrollalias) .and. USED(scrollalias)
	SELECT (scrollalias)
ENDIF
IF oldscreen1 = .f.
	ofrmProfile.lockscreen = .F.
ENDIF
IF WEXIST('PROFILEFORM') .and. TYPE("osetcontrol")="O" .and. !ISNULL(osetcontrol)
	osetcontrol.setfocus()
ENDIF

>Hello,
>I have a grid on a form that contains a column which in turn contains a command button. When the user clicks on the command button all occurences are removed from the grid that does not fit the current filter. Right now though when the user clicks the button all of that works but the next record in line moves to the top of the screen rather than staying put. How can I go about making this look better so that the user clicks on the button and that record and the other records drop out without the next record going to the top of the screen and looking rather ugly?
>
>Thanks for any help.
>
>--Troy
>
>Code from command button
>

>THISFORM.LOCKSCREEN = .T.
>LOCAL lcrecno, lnrecno
>lcrecno = ALLTRIM(DOCUMENT.crecno)
>lnrecno = RECNO("document")
>THIS.PARENT.PARENT.RECORDSOURCE = ""
>UPDATE DOCUMENT ;
>SET DOCUMENT.linclude = .F., ;
>DOCUMENT.lfetch = .F., DOCUMENT.lsend = .F. ;
>WHERE ALLTRIM(crecno) = lcrecno
>TABLEUPDATE(.T.,.T.,"document")
>GO (lnrecno)
>THIS.PARENT.PARENT.RECORDSOURCE = "document"
>WITH THIS.PARENT.PARENT
>	.colrec.CONTROLSOURCE="alltrim(document.crecno)"
>	.colnames.CONTROLSOURCE="document.cname"
>	.coldoc.CONTROLSOURCE="document.cdoctype"
>	.colprop.CONTROLSOURCE = "document.ntype"
>ENDWITH
>THIS.PARENT.REFRESH()
>THISFORM.LOCKSCREEN = .F.
>