>I'm trying to work with triggers, I call a procedure when insert, update or delete records. It seems to work fine but.... if I create a cursor as an image of a triggered table the trigger starts working even on this cursor and that is not what i want to :-).
>I create the trigger with create cursor "cursorname" from array "arrayname" where the array is generated by the Afield fuction.
>
>Thank you
>Alessio

Alessio,

You have to go through the array and clean

to avoid the triggers: elements Array[ ?, 13 to the end]
to avoid RecordValidation as well : elements Array[ ?, 10 to the end]
to avoid RecordValidation and field validation as well : elements Array[ ?, 7 to the end]

See afields in help

an old routine of mine

*--------------------------------------------------------------------------
procedure	CreateCursor(Cursor)
	local x[1], i, j, s
	=afields(x)
	* Eliminate Field Validation Rules, triggers, and the like
	for i = 1 to alen(m.x,1)
		for j = 7 to alen(m.x,2)
			x[m.i,m.j] = ''
		endfor
	endfor
	s = select(0)
	if( used(m.Cursor) )
		use in (m.Cursor)
	endif
	select 0
	create cursor (m.Cursor) from array x
	select (m.s)
endproc
*--------------------------------------------------------------------------