Thanks Nadya. That's pretty close to the code i used finally that did the job.
Jaime

>>Hi All
>>How do i send an email through GW6.5 from my VFP app?
>>
>>TIA
>>Jaime
>
>We used the following program. However, we found some strange problems with GroupWise, so later on we switched to IdsMail, then we switched to MS Outlook for all our users. Anyway, FWIW:
>
>

>********************************************************************
>*  Description.......: MailWithGroupWise - used for sending mails with GroupWise as Mail Client
>*  Calling Samples...: MailWithGroupWise('nnosonov@thewarrengroup.com','SUBJECT HERE','TEXT MESSAGE HERE ','O:\REDP\OUTPUT\CUstomer\Fares\Trwc0122.zip')
>*  Parameter List....: cSendTo,cSubject,cMessage,cAttachment
>*  Created by........: Robert Peirce
>*  Modified by.......: Nadya Nosonovsky 06/14/2002 04:15:37 PM
>********************************************************************
>lparameters cSendTo,cSubject,cMessage,cAttachment
>if vartype(m.cSendTo)<>"C" or empty(m.cSendTo)
>	=messagebox('Invalid Send To parameter passed',48,"Invalid parameter")
>	return -1
>endif
>set message to '    Sending an e-mail...'
>local oGW, lcOldError, lnReturn, loMessage
>lcOldError=on('error')
>on error lnReturn=-1
>lnReturn=0
>oGW=createobject('NovellGroupwareSession')
>if vartype(oGW)='O' && Group Wise object was successfully created	
>	local oMsg, loRecipients, lnRecipients, lnI, lnAttachments
>	oMsg=oGW.Login.RootFolder.messages.add
>	oMsg.Subject = m.cSubject
>	oMsg.BodyText = m.cMessage
>	lnRecipients=alines(laRecipients,strtran(m.cSendTo,";",chr(13)))
>	if vartype(m.cAttachment)='C' and !empty(m.cAttachment)		
>		lnAttachments=alines(laAttachments,strtran(m.cAttachment,";",chr(13)))
>	else
>		lnAttachments = 0 && No attachments
>	endif
>	for lnI=1 to m.lnRecipients
>		cSendTo=laRecipients[m.lnI]
>		if '@' $ m.cSendTo
>			if left(m.cSendTo,5)<>'inet:'
>				m.cSendTo = 'inet:'+ m.cSendTo
>			endif
>			loRecipients=oMsg.Recipients.add(m.cSendTo,'NGW','0')
>		else
>			loRecipients=oMsg.Recipients.AddByDisplayName(m.cSendTo)
>		endif
>		loRecipients.Resolve()
>	endfor
>	for lnI=1 to m.lnAttachments
>		cAttachment=laAttachments[m.lnI]
>		if !file(m.cAttachment)
>			=messagebox("File "+ m.cAttachment+" is not found!",48,'File not found')
>			lnReturn=-1
>			exit
>		endif
>		oMsg.Attachments.add(m.cAttachment)
>	endfor
>	if m.lnReturn=0 && No errors yet
>		oMsg.send
>	endif
>	release oGW
>else
>	lnReturn=SendMails(,,m.cSendTo,m.cSubject,m.cMessage,m.cAttachment) && Wrapper for Nigel's class
>endif
>on error &lcOldError
>return m.lnReturn
>