>George,
>
>Did it turn off the screen saver when the screen saver was active. And how did the exe know when to disable the screen saver, the screen saver couldn't have been active when you clicked on the desktop icon.
>
>Confused???
>
>Ray

Here's the full test program:

#DEFINE SPI_GETSCREENSAVEACTIVE    16
#DEFINE SPI_SETSCREENSAVEACTIVE    17
LOCAL lniparm, lnvparm, lnresult, lcmsg
DECLARE SHORT SystemParametersInfo IN Win32API;
  INTEGER uiAction, SHORT uiParam,;
  INTEGER @pvParam, INTEGER fWinIni
lnvparm = 0
lnresult = SystemParametersInfo(SPI_GETSCREENSAVEACTIVE, 0, @lnvparm, 0)
IF lnresult # 0
  DECLARE SHORT SystemParametersInfo IN Win32API;
    INTEGER uiAction, SHORT uiParam,;
    INTEGER pvParam, INTEGER fWinIni
  IF lnvparm = 0
    * Disabled, so enable it
    lniparm = 1
    lcmsg = "The screen saver has been enabled!"
  ELSE
    * Enabled, so disable it
    lniparm = 0
    lcmsg = "The screen saver has been disabled!"
  ENDIF
  lnresult = SystemParametersInfo(SPI_SETSCREENSAVEACTIVE, lniparm, 0, 0)
  IF lnresult # 0
    = MESSAGEBOX(lcmsg, 64, "Screen Saver Test")
  ELSE
    = MESSAGEBOX("Unable to set the screen saver state!", 64, "Screen Saver Test")
  ENDIF
ELSE
  = MESSAGEBOX("Unable to retrieve Screen Saver setting!", 64, "Screen Saver Test")
ENDIF
RETURN

Hope this clears up any confusion.