Your're welcome. You may also be interested in this. I am working on streamlining the same thing basically and researching the pdf sdk I found a way to read the values from the pdf form using automation and/or javascript from vfp:

*--This example Requires the pdf form test.pdf with the following formfield 
*--names (all are case sensitive):

*        "AGENCY.NAME"
*        "AGENCY.ADDR1"
*        "AGENCY.CITYSTZIP"


sFieldName  = "AGENCY.NAME"
sFieldName2 = "AGENCY.ADDR1"
sFieldName3 = "AGENCY.CITYSTZIP"

AcroExchAVDoc = CreateObject("AcroExch.AVDoc")

sfileName = "C:\acordforms\test\test.pdf"
IF !FILE(sFileName)
	=MESSAGEBOX('Cannot locate: '+sfilename)
	sFileName=GETFILE('pdf','PDF File:','Open',1,'Please select a pdf file with the formfield AGENCY.ADDR1')
	IF !FILE(sFileName)
		=MESSAGEBOX('Cannot locate: '+sfilename)
		RETURN
	ENDIF
ENDIF

AcroExchAVDoc.Open(sFileName, "")
AcroForm = CreateObject("AFormAut.App")
AcroFields = AcroForm.Fields

*--Get the value of the first field AGENCY.NAME in our test.pdf
AcroField  = AcroFields.Item(sFieldName)
*--Get the value of the 2nd field AGENCY.ADDR1 in our test.pdf
AcroField2 = AcroFields.Item(sFieldName2)

MESSAGEBOX(PADR(PADL("FORMFIELD AGENCY.NAME value:",40),80)+CHR(13)+AcroField.Value+CHR(13)+CHR(13);
          +PADR(PADL("FORMFIELD AGENCY.ADDR1 value:",40),80)+CHR(13)+AcroField2.Value,0+64+4096,"Value Retrieved by Automation")

*--Get the value of the citystzip formfield using javascript
sJS = "event.value = this.getField("+"'"+sFieldName3+"'"+").value;"
sValue = AcroForm.Fields.ExecuteThisJavaScript(sJS)

=MESSAGEBOX(PADR(PADL("AGENCY.CITYSTZIP value:",40),80)+CHR(13)+sValue+CHR(13),0+64+4096,"Value Retrieved by JavaScript")