>hi all,
>
>i need to open excel sheet from another directory or server,
>via myform'
>and modify some operatins at excel sheet,and return back to mydirectory(myform).
>
>thanks
>m.qasem
>via myform

Mohammed,
Not clear what you mean. Below sample:
-Creates excel file c:\temp\myFile.xls with names from testdata!employee
-Opens that xls file
-Inserts customer Company, Contact names starting from D5 as top left corner, autoformats the inserted section with one of colorful formats and shows xls
Note that you don't need to change default directory.

local lcXLSFile,lcTemp
lcXLSFile = "c:\temp\myFile.xls"
select First_Name, last_Name from employee into cursor crsTemp
copy to (m.lcXLSFile) type xls
Select Company,Contact from customer into cursor crsTemp
lcTemp = sys(2015)+'.tmp'
copy to (m.lcTemp) type delimited with "" with tab
_cliptext = "Company"+Chr(9)+"Contact Name"+Chr(13)+FileToStr(m.lcTemp)
erase (m.lcTemp)
use in "crsTemp"

#define xlRangeAutoFormatColor2 8
oExcel = createobject("Excel.Application")
with oExcel
 .WorkBooks.Open(m.lcXLSFile)
 With .ActiveWorkBook.ActiveSheet
 	.Range("D5").PasteSpecial
 	.Application.Selection.Columns.Autoformat(xlRangeAutoFormatColor2)
 	.Range("A1").Activate
 endwith
 .Visible = .T.
endwith

Cetin