Hi Julia,

You would get this error if you hit enter after entering abbreviation in the command window because Intellisence returns it unmodified and VFP execute it. If you hit space, there's no error. Below I included a litle bit simplified version of your script.

LPARAMETERS toFoxCode

IF toFoxcode.Location = 0
   RETURN toFoxCode.UserTyped
ENDIF

toFoxcode.valuetype = "V"

LOCAL lcTxt, lcName, lcComment
lcName = Inputbox('Input the name of procedure you wish to use: ')
lcVersion = "Visual FoxPro" + VERSION(4)

TEXT TO lcTxt  TEXTMERGE NOSHOW
***********************************************************************
* Program....: <<UPPER(lcName)>>
* Date.......: <<DATETIME()>>
* Compiler...: <<lcVersion>>
* Purpose....: ~
***********************************************************************
FUNCTION <<Upper(lcName)>>()

	RETURN .T.
ENDFUNC
ENDTEXT
RETURN lcTxt

>
>Sorry for the delay. Here is my code. When I try to enter the abbreviated characters in the command window, shouldn't I get what I typed in back rather than "Unrecognized Command Verb" error since location is 0? Thank you for your help.

>LPARAMETERS toFoxCode
>
>IF toFoxcode.Location = 0
>   RETURN toFoxCode.UserTyped
>ENDIF
>
>toFoxcode.valuetype = "V"
>
>LOCAL lcTxt, lcName, lcComment
>STORE "" TO lcTxt, lcName, lcComment
>#DEFINE CRLF CHR(13)+CHR(10)
>
>lcName = Inputbox('Input the name of procedure you wish to use: ')
>lcVersion = "Visual FoxPro" + VERSION(4)
>
>TEXT TO lcTxt NOSHOW
>***********************************************************************
>* Program....: <<UPPER(lcName)>>
>* Date.......: <<DATETIME()>>
>* Compiler...: <<lcVersion>>
>* Purpose....: ~
>***********************************************************************
>FUNCTION <<Upper(lcName)>>()
>
>	RETURN .T.
>ENDFUNC
>ENDTEXT
>RETURN TEXTMERGE(lcTxt)