>Hi Everybody,
>
>I am looking for a control which shows the size of a point. Like a slider bar and a graphic point. When user slides the slider bar, he gets a circle with different diameters. Higher the number, bigger the circle diameter.
>
>Does anybody has any clue for me?
>
>Thank you,
>Ali

Public oForm
oForm = CreateObject('myForm')
oForm.Show

Define class myForm As Form
Height=530
Width=500
Add Object myCircle As Shape With ;
  Left=250,Top=250,Height=0,Width=0,Curvature=99
Add Object mySlider As OleControl With ;
  Left=0,Top=502,Width=500,OleClass = "MsComCtlLib.Slider.2"
  Procedure mySlider.Init
  	this.Max=500
  EndProc
  Procedure mySlider.Change
    With Thisform.myCircle
      Store This.Value To .Height,.Width
      Store (This.Max - This.Value) / 2 To .Left,.Top
    Endwith
  Endproc
  Procedure mySlider.KeyDown
    Lparameters keycode, Shift
    This.Change()
  Endproc
  Procedure mySlider.MouseMove
    Lparameters Button, Shift, x, Y
    This.Change()
  Endproc
enddefine

Cetin