>Anyone who knows of a walkthrough on how to use the .gettablefrompalmpilot and/or .copytabletopalmpilot of the Satellite Form Active X.
>
>Thanks!
Yes, it's really simple.

This.GetTableFromPalmPilot("c:\Data\Actos.Dbf","SMSF","Sddi_PalmDB.dll",0,1,0)

This.CopyTableToPalmPilot("c:\Data\Canal.Dbf","SMSF","Sddi_PalmDB.dll",0,1,0)

This is call from the HotSyncStatus Event of the ActiveX.

Remember you will have a parameter telling you wich event has ocurred.

This is my complete code if it's helpfull for you:

*** ActiveX Control Event ***
LPARAMETERS statuscode, param
*Set Step On
Do Case
	Case statuscode=1 &&HotSyncStart Operation
		Thisform.Contador=1
		Do Case
			Case Thisform.Opciones1.Value=1 &&Copiar Tablas de HandHeld Hacia PC
				Thisform.Enviando=.F.
				Thisform.Barra1.Max=1
				Thisform.Etiqueta2.Caption="Obteniendo Tabla de Actos"
				This.GetTableFromPalmPilot(Goapp.RutaPalm+"Actos.Dbf","SMSF","Sddi_PalmDB.dll",0,1,0)
			Case Thisform.Opciones1.Value=2 &&Copiar Tablas de Pc Hacia HandHeld
				Thisform.Barra1.Max=5
				Thisform.Enviando=.T.
				Thisform.Etiqueta2.Caption="Enviando Solicitud de Copia para Precios"
				This.CopyTableToPalmPilot(Goapp.RutaPalm+"Precios.Dbf","SMSF","Sddi_PalmDB.dll",0,1,0)
				Thisform.Etiqueta2.Caption="Enviando Solicitud de Copia para Canal"
				This.CopyTableToPalmPilot(Goapp.RutaPalm+"Canal.Dbf","SMSF","Sddi_PalmDB.dll",0,1,0)
				Thisform.Etiqueta2.Caption="Enviando Solicitud de Copia para Domicilios"
				This.CopyTableToPalmPilot(Goapp.RutaPalm+"Domicili.Dbf","SMSF","Sddi_PalmDB.dll",0,1,0)
				Thisform.Etiqueta2.Caption="Enviando Solicitud de Copia para Usuarios"
				This.CopyTableToPalmPilot(Goapp.RutaPalm+"Usuarios.Dbf","SMSF","Sddi_PalmDB.dll",0,1,0)
				Thisform.Etiqueta2.Caption="Enviando Solicitud de Copia para Actos"
				Use Goapp.RutaPalm+"Actos.Dbf" Exclusive In 0
				Zap
				Use
				This.CopyTableToPalmPilot(Goapp.RutaPalm+"Actos.Dbf","SMSF","Sddi_PalmDB.dll",0,1,0)
				Thisform.Etiqueta2.Caption="Copiando Tablas a HandHeld, Por Favor Espere..."
		EndCase
	Case statuscode=3 &&HotSyncCommandComplete Operation
		Do Case
			Case !Thisform.Enviando
				If param=1  &&Fin de Sincronización
					Thisform.Etiqueta2.Caption="Tabla de Actos de Compra Obtenida; Críticando, por favor espere..."
					Thisform.Sincronizar()
				Else &&Sincronización Exitosa
				EndIf
			Case Thisform.Enviando
				If param=1  &&Fin de Sincronización
					Do Case
						Case Thisform.Contador=1
							Thisform.Etiqueta2.Caption="Tabla de Precios Copiada"
						Case Thisform.Contador=2
							Thisform.Etiqueta2.Caption="Tabla de Canal Copiada"
						Case Thisform.Contador=3
							Thisform.Etiqueta2.Caption="Tabla de Domicilios Copiada"
						Case Thisform.Contador=4
							Thisform.Etiqueta2.Caption="Tabla de Usuarios Copiada"
						Case Thisform.Contador=5
							Thisform.Etiqueta2.Caption="Tabla de Actos Copiada"
					EndCase
				Else &&Sincronización No Exitosa
				EndIf
		EndCase
		Thisform.Contador = Thisform.Contador + 1
		Thisform.Barra1.Value = Thisform.Barra1.Value + 1
	Case statuscode=2 &&HotSyncEnd Operation
		If param=1  &&Transmisión de Archivo Exitosa
			Thisform.Etiqueta2.Caption="Proceso Finalizado sin Errores"
			MessageBox("La Sincronización de Archivos Solicitada se Realizó sin Errores",64,"TNS DATA")
		Else &&Transmisión de Archivo Exitosa
			Thisform.Etiqueta2.Caption="Proceso Finalizado con Errores"
			MessageBox("Ocurrio un Error en la Transmisión de Archivos",16,"TNS DATA")
		EndIf
EndCase

Luis Navas