Hi,
Do you have something like this in your script.

<snip>
>One thing that is very inconvenient with it at this point is the fact that I either have to start over from >scratch or edit it in text mode when I need to change something.

Well HOW ELSE would you make changes, just think about it and it happens, wake up.

[Files]
;**********************************************************************
;
;	workstation component files
;
;**********************************************************************
Source: .\Distrib\gdiplus.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: sharedfile uninsneveruninstall restartreplace; Components: workstation
Source: .\Distrib\GDIPLUS.DLL; DestDir: {sys}; Flags: regserver uninsneveruninstall sharedfile onlyifdoesntexist noregerror; Components: workstation
Source: .\Distrib\MSVCR71.DLL; DestDir: {sys}; Flags: uninsneveruninstall onlyifdoesntexist; Components: workstation

; Microsoft Visual C++ 7.1 Runtime DLL
; If one does not already exist, write a copy of MSVCR71.DLL in the system directory
; so register VFP9R.DLL will succeed. Use the deleteafterinstall to remove this file
; after installation is complete. The deleteafterinstall flag will not remove existing
; files that were not replaced during installation.
Source: .\Distrib\msvcr71.dll; DestDir: {sys}; Flags: onlyifdoesntexist deleteafterinstall; Components: workstation
; If a copy of msvcr71.dll is needed temporarily in {cf}\Microsoft Shared\VFP, uncomment this line.
Source: .\Distrib\msvcr71.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: onlyifdoesntexist deleteafterinstall; Components: workstation
; Write the application's copy of MSVCR71.DLL to the app directory.
Source: .\Distrib\msvcr71.dll; DestDir: {code:GetAppDir}; Flags: onlyifdoesntexist; Components: workstation

; Microsoft Visual FoxPro 9.0 Runtime Support Libraries
Source: .\Distrib\vfp9r.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: regserver sharedfile uninsneveruninstall restartreplace; Components: workstation
Source: .\Distrib\vfp9t.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: sharedfile uninsneveruninstall restartreplace; Components: workstation
Source: .\Distrib\vfp9renu.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: sharedfile uninsneveruninstall restartreplace; Components: workstation

; Object assisted Reporting
Source: .\Distrib\reportbuilder.app; DestDir: {code:GetAppDir}; Components: workstation
Source: .\Distrib\reportpreview.app; DestDir: {code:GetAppDir}; Components: workstation
Source: .\Distrib\reportoutput.app; DestDir: {code:GetAppDir}; Components: workstation

; Microsoft HTML Help Runtime Files for Visual FoxPro 9.0
Source: .\Distrib\foxhhelp9.exe; DestDir: {cf}\Microsoft Shared\VFP; Flags: sharedfile uninsneveruninstall restartreplace; Components: workstation
Source: .\Distrib\foxhhelpps9.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: regserver sharedfile restartreplace uninsneveruninstall; Components: workstation

; MSCOMCTL

Source: .\Distrib\mscomctl.dep; DestDir: {sys}; Flags: sharedfile uninsneveruninstall restartreplace; Components: workstation
Source: .\Distrib\mscomctl.srg; DestDir: {sys}; Flags: sharedfile uninsneveruninstall restartreplace; Components: workstation
Source: .\Distrib\mscomctl.ocx; DestDir: {sys}; Flags: regserver sharedfile uninsneveruninstall restartreplace; Components: workstation

; XML4
Source: .\Distrib\msxml4r.dll; DestDir: {sys}; Flags: sharedfile uninsneveruninstall restartreplace; Components: workstation
Source: .\Distrib\msxml4.dll; DestDir: {sys}; Flags: regserver sharedfile uninsneveruninstall restartreplace; Components: workstation

>I may have just done so, however.
>
>I created a distributable disc, and had a friend load it on his computer. Its first message: "Cannot locate the Microsoft Visual FoxPro support library."
>
>I remember I had a similar problem the first time I used InstallShield because the example was incomplete. Is there a similar trap with Inno?
>
>One thing that is very inconvenient with it at this point is the fact that I either have to start over from scratch or edit it in text mode when I need to change something.
>
>1. Did I miss the library files, and if so how do I get that straightened up?
>
>2. Is there a way to avoid the text editor as well as restarting from scratch?
>
>
>Thanks