Hi Lynda
here is your sample:
****************************************************************************
* This example will show you how to create a very simple runonce configuration.
*
http://biopdf.com/purchase.php && PriceList
*
http://biopdf.com/guide/settings.php && BullZip-Printer-Configuration
* You can run it without any change, if BULLZIP-PDF-Printer is installed
****************************************************************************
CLEAR
? REPLICATE("*",80)+CHR(13)+CHR(10)+"Program started"+CHR(13)+CHR(10)+REPLICATE("*",80)+CHR(13)+CHR(10)
LOCAL lcCurDir, lcPrintFile, lcPDFName, lcObj, lcPrinter, loWord, lcSavePrinter
lcCurDir = SYS(5)+CURDIR()
lcPrintFile = "Example.doc"
lcPDFName = "ExampleOut.pdf"
PrepareTestFolderAndDoc(lcCurDir, lcPrintFile, lcPDFName)
************************************************************
* Create the COM object to control the printer.
lcObj = CreateObject("BullZIP.PDFPrinterSettings")
lcObj.SetValue("Output" ,lcCurDir + "\out\"+lcPDFName)
lcObj.SetValue("WatermarkText" ,"D r a f t" )
lcObj.SetValue("WatermarkColor" ,"#FF9900")
lcObj.SetValue("ShowSettings" ,"never" )
lcObj.SetValue("ShowPDF" ,"no" )
lcObj.SetValue("ConfirmOverwrite" ,"no" )
lcObj.SetValue("ShowProgress" ,"yes" )
lcObj.SetValue("ShowProgressFinished","no" )
lcObj.WriteSettings(.t.)
lcPrinter = lcObj.GetPrinterName
*MODIFY COMMAND (lcobj.GetSettingsFileName) && opens ini-File
************************************************************
* Print Word-Document
loWord = CREATEOBJECT("Word.application")
WITH loWord
lcSavePrinter = .ActivePrinter && save DefaultPrinter
.ActivePrinter = lcPrinter && BULLZIP Printer
.documents.open((lcCurDir + "\in\"+lcPrintFile))
.Application.PrintOut(.t.)
.ActivePrinter = lcSavePrinter && restore DefaultPrinter
.visible = .f.
.left = -32000 && make Word invisible.
.documents.close(.f.)
.quit
ENDWITH
STORE .null. TO lcObj, loWord
? REPLICATE("*",80)+CHR(13)+CHR(10)+"Program ended"+CHR(13)+CHR(10)+REPLICATE("*",80)
*******************************************************************************
* EndOfProgram
*******************************************************************************
FUNCTION PrepareTestFolderAndDoc (lcCurDir, lcPrintFile, lcPDFName)
IF !DIRECTORY((lcCurDir)+"in")
mkdir(lcCurDir+"in")
ENDIF
IF !DIRECTORY((lcCurDir)+"out")
mkdir(lcCurDir+"out")
ENDIF
lcDocText = REPLICATE("Just a Test. ",8) + CHR(13)+CHR(10)
lcDocText = REPLICATE(lcDocText,20) + CHR(13)+CHR(10)
IF !FILE((lcCurDir)+"in\"+(lcPrintFile))
************************************************************
* Create sample Word-Document
PUBLIC loWord, lox
loWord = CREATEOBJECT("Word.application")
lox = loword.Application
WITH loWord
.documents.add("Normal",.f.,0)
.Selection.TypeText(lcDocText)
.visible = .f.
.left = -32000 && make Word invisible.
.ActiveDocument.SaveAs((lcCurDir)+"in\"+(lcPrintFile))
.documents.close(.f.)
.quit
ENDWITH
STORE .null. TO loWord
ENDIF
ENDFUNC
***********************************************************
Hope that helps
Christoph