Take a look at message#726191 - I don't yet understand how it can create the AVFPdemo2 virtuals on XP and not new ones in WebAppBuilder - they use the same PostSetup routines from the same dll to create a virtual. In WebAppBuilder, what was the name of the new application and directory that you put in? Does it pop up the browser(this will tell us if it ran PostSetup)? Did you leave in 'LOCALHOST' for Domain Name and 'Default Web Site' for Web Site?
I don't have a copy of XP so I'd appreciate any help. It always works for me on Win 2000 Pro and Server.
The following is the relevant code that is run from WebAppBuilder and Setup. COuld you run this directly from VFP and see if it works on your XP?:

************************************************************************
* setup :: setIISAdmin
*********************************
*** Function: setIISAdmin Method. Set virtual with IISADMIN. 
************************************************************************
FUNCTION setIISAdmin
LPARAMETERS cProd,cFolder,cDomain,cSite
LOCAL loIIS,lcRootPath,loVirtual
lcRootPath=""
loIIS=GetObject("IIS://" + cDomain + "/W3SVC")
FOR EACH oSite IN loIIS
  IF VAL(oSite.name)#0
     IF oSite.ServerComment == cSite
        lcRootPath=oSite.ADsPath+"/ROOT"
     ENDIF
  ENDIF
ENDFOR
IF EMPTY(lcRootPath)
	THIS.cError="Could not find IISAdmin Root"
	RETURN
ELSE    
	loIIS=GetObject(lcRootPath)
	* Create Script Dir
	loVirtual=loIIS.CREATE("IIsWebVirtualDir",cProd)
	IF TYPE("loVirtual")# "O" && possibly already exists
			loVirtual = GETOBJECT(lcRootPath+"/"+cProd)
			IF TYPE("loVirtual")# "O" 
				THIS.cError="Could not create executable virtual"
				RETURN
			ENDIF
	ENDIF  
	lcAppRoot = loIIS.AppRoot+'/'+ cprod  && for debug support
	loVirtual.AppRoot = lcAppRoot  && for debug support
	loVirtual.AppFriendlyName = cProd
	loVirtual.AppIsolated = 2  && 1 = High(unload), 2 = pooled(unload), 0 = inprocess
	loVirtual.AccessRead=.T.
	loVirtual.AccessExecute=.F.
	loVirtual.AccessScript=.T.
	loVirtual.AuthBasic=.T.
	loVirtual.AuthNTLM=.T.
	*loVirtual.AuthFlags = 4
	loVirtual.Path = IIF(EMPTY(cFolder),THIS.cAppStartPath,cFolder+"\")+cProd+[\wwwroot]
	loVirtual.SetInfo()	
	
	* Create Read Dir
	loVirtual=loIIS.CREATE("IIsWebVirtualDir",cProd+"r")  
	IF TYPE("loVirtual")# "O" && possibly already exists
			loVirtual = GETOBJECT(lcRootPath+"/"+cProd+"r")
			IF TYPE("loVirtual")# "O" 
				THIS.cError="Could not create read virtual"
				RETURN				
			ENDIF
	ENDIF
	loVirtual.PATH=IIF(EMPTY(cFolder),THIS.cAppStartPath,cFolder+"\")+cProd+"r"
	loVirtual.AppCreate(.T.)
	loVirtual.AppFriendlyName=cProd+"r"
	loVirtual.AccessRead=.T.
	loVirtual.AccessExecute=.F.
	loVirtual.AuthBasic=.T.
	loVirtual.AuthNTLM=.T.
	loVirtual.SetInfo()
	
ENDIF
RETURN
ENDFUNC
************************************************************************

Your latest download loaded with no problem and created the AVFPdemo2 virtual directories without any problem. Also the default screen came up as expected. Good job.
>
>However, when I use the Webappbilder to create my own applicaton, it creates the correct directories and two subfolder, but not the virtual directories. Is this because of I am using XP or some other reason?
>
>I am using VFP7 - running XP Profession.
>
>Gaylen